Staż pracy w Excelu: suma kilku okresów zatrudnienia

Pracownik przynosi cztery świadectwa pracy, a ty masz podać łączny staż w latach, miesiącach i dniach. DATA.RÓŻNICA policzy jeden okres. Przy kilku okresach sama nie wystarczy, bo sumę dni trzeba jeszcze przeliczyć na miesiące, a miesiące na lata. Poniżej gotowy układ arkusza: trzy formuły na wiersz i trzy formuły na sumę.

Jeśli dopiero poznajesz funkcje daty, zacznij od lekcji Funkcje daty w Excelu: DZIŚ, DATA.RÓŻNICA, DZIEŃ.ROBOCZY.

Trzy zasady, zanim wpiszesz formułę

1. Ostatni dzień zatrudnienia się liczy. Okres od 01.01.2020 do 31.12.2020 to pełny rok. DATA.RÓŻNICA liczy do daty końcowej bez niej i zwróci 0 lat. Dlatego w formułach do daty końcowej dodajemy 1.
2. Przy sumowaniu 30 dni to miesiąc, a 12 miesięcy to rok. Okresy zatrudnienia się sumuje, a ich ciągłość nie jest wymagana. Stosuje się wtedy art. 114 Kodeksu cywilnego: miesiąc liczy się za 30 dni.
3. Ten sam czas liczysz raz. Jeśli ktoś pracował jednocześnie u dwóch pracodawców, wspólny okres wchodzi do stażu tylko raz.

Które okresy w ogóle wliczyć do stażu, rozstrzygają przepisy, a nie Excel. Od 2026 roku zmieniły się zasady dla części umów innych niż umowa o pracę. Arkusz zaczyna się w momencie, gdy masz już listę dat.

Krok 1. Tabela okresów

Każdy okres zatrudnienia w osobnym wierszu: w kolumnie A pracodawca, w B data początku, w C data końca. Posortuj wiersze rosnąco według daty początku, przyda się to przy kontroli nakładania się okresów.

Krok 2. Lata, miesiące i dni dla każdego okresu

W kolumnie D pełne lata:

=DATA.RÓŻNICA(B2;C2+1;"Y")

W kolumnie E miesiące ponad pełne lata (wynik od 0 do 11):

=DATA.RÓŻNICA(B2;C2+1;"YM")

W kolumnie F pozostałe dni:

=C2+1-NR.SER.DATY(B2;12*D2+E2)

NR.SER.DATY przesuwa datę początku o policzone już lata i miesiące. To, co zostaje do daty końcowej, to dni.

Dlaczego nie jednostka „MD”? DATA.RÓŻNICA ma jednostkę „MD”, która wprost zwraca dni. Microsoft w dokumentacji funkcji nie zaleca jej używania, bo w części przypadków daje wynik ujemny, zero albo niedokładny. Formuła z NR.SER.DATY tego problemu nie ma.

Kolumna Dni pokazuje datę zamiast liczby? Excel dziedziczy format daty z kolumny C. Zaznacz kolumnę F i ustaw format Ogólny.

DATA.RÓŻNICA nie podpowiada się przy wpisywaniu. To normalne, funkcja jest w Excelu od czasów Lotusa i nie ma jej na liście podpowiedzi. Wpisz ją ręcznie w całości.

Krok 3. Suma z przeliczeniem dni i miesięcy

Najpierw zwykłe sumy kolumn, np. w I2, J2 i K2:

=SUMA(D2:D5)
=SUMA(E2:E5)
=SUMA(F2:F5)

W przykładzie wychodzi 12 lat, 17 miesięcy i 48 dni. Takiej liczby nie podasz w świadectwie ani w kartotece, więc przeliczamy od dni w górę. W I4, J4 i K4:

Dni (reszta z dzielenia przez 30):

=MOD(K2;30)

Miesiące (suma miesięcy plus pełne miesiące z dni, reszta z dzielenia przez 12):

=MOD(J2+CZ.CAŁK.DZIELENIA(K2;30);12)

Lata (suma lat plus pełne lata z miesięcy):

=I2+CZ.CAŁK.DZIELENIA(J2+CZ.CAŁK.DZIELENIA(K2;30);12)

48 dni to 1 miesiąc i 18 dni. Miesięcy robi się 18, czyli 1 rok i 6 miesięcy. Lat 12 plus 1. Łączny staż: 13 lat, 6 miesięcy i 18 dni.

Wynik w jednej komórce, np. do wydruku:

=I4&" l. "&J4&" m. "&K4&" d."

Skróty „l.”, „m.”, „d.” oszczędzają kłopotu z odmianą. Pełne słowo „lat” przy wyniku 1, 2 czy 3 brzmiałoby źle.

Pracownik nadal pracuje

W ostatnim okresie nie ma daty końca. Zamiast zmieniać formuły, dodaj kolumnę pomocniczą z datą do obliczeń i w formułach z kroku 2 odwołuj się do niej zamiast do kolumny C:

=JEŻELI(C2="";DZIŚ();C2)

Staż policzy się do dzisiaj włącznie i będzie się aktualizował przy każdym otwarciu pliku.

Dwie rzeczy do sprawdzenia ręcznie

Nakładające się okresy. Excel ich sam nie usunie, ale może je wskazać. Przy wierszach posortowanych według daty początku wpisz w G3 i skopiuj w dół:

=JEŻELI(B3<=C2;"nakłada się";"")

Przy oznaczonym wierszu zdecyduj, co zrobić. Najczęściej wystarczy przesunąć datę początku na dzień po końcu poprzedniego okresu, żeby wspólny czas nie wszedł do sumy dwa razy.

Okresy zaczynające się 29, 30 lub 31 dnia miesiąca. Miesiące mają różną długość i przy takich datach wynik bywa o dzień inny, niż podałaby osoba licząca na kartce. Przykład: okres od 31.01.2021 do 28.02.2021 formuła pokaże jako 1 miesiąc i 1 dzień. Przy takich datach porównaj wynik z dokumentem.

Podsumowanie

Ten sam układ działa dla każdej liczby okresów. Wystarczy rozszerzyć zakresy w funkcjach SUMA.

Sprawdź swój poziom Excela

Pobierz darmowy test z 15 zadaniami i sprawdź, ile naprawdę umiesz w Excelu.